***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 09, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4FL13A  A K 
.param
+vc0 = 8.206e-10	   vc1 = 6.366e-11        vc2 = 1.000		vc3 = 1.205e-12		vc4 = 4.935e-1
+tc1 = 2.421e-2	   tc2 = 1.671e-2		  tc3 = 1.501e-2		tc4 = 3.371e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {1.705e-1*min(i,0)}
d1 A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 9.215E-15	       n = 1.009          rs = 1.000e-6
+ibv = 1.0e-3		 nbv = 0.5		  bv = 15.15
+ikf = 1.502
***** capacitance parameter *****
+cjo = 1.020e-9	   m = 3.317e-1		  vj = 5.995e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		      eg = 1.130		      xti = 3
+tikf = 6.0e-3          ;trs1 = 1e-3		trs2 = -1e-5
+tbv1 =7.637e-4	      tbv2 = -7.452e-8
.ends P4FL13A
*$
